How does JavaFX relate in the WorkPlace.

[Justin Char]

How does JavaFX relate in the WorkPlace.

Justin

[Gail Anderson]

Hi Justin,

I'm not sure I understand your question. Can you be more specific?

[Justin Char]

I mean how will this enhance the apps, adhocs, and programs I do in JAVA.

Was is this going to give me above and beyound what I am doing not using it.

[Gail Anderson]

With JavaFX, you can build a really nice graphics-based UI more quickly and easily than using Swing, for example.

Another recent post referenced this Swing demo program: Launch TransformerDemo

With JavaFX, you can easily implement the 3 transformer sliders by binding properties of any objects to the slider values. So, to hook up a rectangle to 3 sliders that control angle, scale, and shear you use the transforms property:

package uicomponenttest;

import javafx.scene.control.Button;
import javafx.scene.control.Slider;
import javafx.scene.layout.HBox;
import javafx.scene.layout.VBox;
import javafx.scene.paint.Color;
import javafx.scene.Scene;
import javafx.scene.shape.Rectangle;
import javafx.scene.transform.Rotate;
import javafx.scene.transform.Scale;
import javafx.scene.transform.Shear;
import javafx.stage.Stage;


def rotateSlider = Slider {
    min: 0.0
    max: 360.0
    value: 0.0
}

def shearSlider = Slider {
    min: 0.0
    max: 1.0
    value: 0.0
}

def scaleSlider = Slider {
    min: 0.0
    max: 2.0
    value: 1.0
}

def rectangle = Rectangle {
    width: 50
    height: 80
    fill: Color.BLUE
    transforms: [
        Shear { x: bind shearSlider.value, y : 0.0 },
        Rotate { pivotX : 25, pivotY : 40, angle: bind rotateSlider.value },
        Scale { x : bind scaleSlider.value, y : bind scaleSlider.value }
        ]
}

def button = Button {
    text: "Reset"
    action: function() {
        rotateSlider.value = 0.0;
        scaleSlider.value = 1.0;
        shearSlider.value = 0.0;
    }
}

Stage {
    title: "UI Components"
    width: 650
    height: 300
    scene: Scene {
        content: VBox {
            spacing: 50
            layoutX: 30
            layoutY: 30
            content: [
                        HBox {
                            spacing: 50
                            content: [  rectangle, button ]
                        },
                        HBox {
                            spacing: 50
                            content: [  rotateSlider, shearSlider, scaleSlider ]
                        }
                    ]
        }
    }
}

Any Node (including UI controls) can be transformed.

You can also provide effects, animation, and manipulate a 2D graphics space.

You can still leverage your Java knowledge, since calling Java APIs is totally transparent.

JavaFX is easy to learn and its declarative style makes code concise and easy to read, as the above example hopefully shows.

I would urge you to check out JavaFX and see if you like it!