String manipulation in XSLT programming

[smitha rai]

Hi,

I am a new to XSL programming. I have a requirement to add slash at every 4th character in a string. For example, a string value of 'abcdefghijklmn' to be translated to 'abcd/efgh/ijkl/mn'. Appreciate if someone help me out.

Regards,

Smitha

[g tsuji]

I would guess you mean in xslt 1.0, otherwise, it is less tricky in 2.0. This the named template, nothing original just cooking it up, doing that.

<xsl:template name="string_manip">
    <xsl:param name="sin" />
    <xsl:param name="separator" />
    <xsl:param name="interval" />
    <xsl:choose>
        <xsl:when test="string-length($sin) < number($interval)+1">
            <xsl:value-of select="$sin" />
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="concat(substring($sin,1,number($interval)), $separator)" />
            <xsl:call-template name="string_manip">
                <xsl:with-param name="sin" select="substring($sin, number($interval)+1)" />
                <xsl:with-param name="separator" select="$separator" />
                <xsl:with-param name="interval" select="number($interval)" />
            </xsl:call-template>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

I hope you know how to call a named template? This is an illustration calling at a context node with separator "/" and for every 4 character block.

    <xsl:call-template name="string_manip">
        <xsl:with-param name="sin" select="." />
        <xsl:with-param name="separator" select="'/'" />
        <xsl:with-param name="interval" select="4" />
    </xsl:call-template>

[smitha rai]

Hi g tsuji,

Working great. Thanks a lot. Yes I am using XSLT 1.0.

Smitha

[g tsuji]

Thanks for the feedback. Sounds great you've got the idea.

Just to make a further note on my own post as I read it. On line #6 of the template, it now reads:

line#6-> <xsl:when test="string-length($sin) < number($interval)+1">

I can assure you it has been made such due to the toy formatter (yes, it is for that just a toy). I had scripted it like this:

line#6-> <xsl:when test="string-length($sin) &lt; number($interval)+1">

I have to write &_amp;lt; (without underscore) this time to make it appears properly! and it should be read as such.

ps: I don't see the point of adopting a toy formatter that betrays codes and that the site cannot or not allowed to customize to counter a feature like that. Not more than encouraging members to use code-tag all the time. But coderanch is not alone, so I shouldn't be too harsh on it.