Why and when to override data method in Action script using flex comp or event ?

[Prabhat Ranjan]

Hi,

override public function set data(valuebject):void {

Regards,
Prabhat

[Iftikhar Arain]

This is usually used in ItemRenderer.

For complete understanding read the blog.
http://blogs.adobe.com/aharui/2008/02/checkbox_selection_in_datagrid.html

Scenario.

List of check boxes with labels. Values retuned from the server are date of birth.

12-12-2010 <check box>
12-11-2010 <check box>
12-10-2010 <check box>
12-05-2010 <check box>

intead of above we want to show.

10 years old <check box>
5 years old <check box>
2 years old <check box>
8 years old <check box>

set data() can be used for this purpose.

e.g - 2

Values returned from teh server are first name and last name and you want to show them as one label.

set data() can be override to display the First Name , Last Name as one string.


Hope this will help.

package 
{
import flash.display.DisplayObject;
import flash.events.KeyboardEvent;
import flash.events.MouseEvent;
import flash.text.TextField;
import mx.controls.CheckBox;
import mx.controls.dataGridClasses.DataGridListData;
import mx.controls.listClasses.ListBase;

/** 
 *  The Renderer.
 */
public class CheckBoxRenderer extends CheckBox
{

	public function CheckBoxRenderer()
	{
		focusEnabled = false;
	}

	override public function set data(value:Object):void
	{
		super.data = value;
		invalidateProperties();
	}
	
	override protected function commitProperties():void
	{
		super.commitProperties();
		if (owner is ListBase)
			selected = ListBase(owner).isItemSelected(data);
	}

	/* eat keyboard events, the underlying list will handle them */
	override protected function keyDownHandler(event:KeyboardEvent):void
	{
	}

	/* eat keyboard events, the underlying list will handle them */
	override protected function keyUpHandler(event:KeyboardEvent):void
	{
	}

	/* eat mouse events, the underlying list will handle them */
	override protected function clickHandler(event:MouseEvent):void
	{
	}

	/* center the checkbox if we're in a datagrid */
	override protected function updateDisplayList(w:Number, h:Number):void
	{
		super.updateDisplayList(w, h);

		if (listData is DataGridListData)
		{
			var n:int = numChildren;
			for (var i:int = 0; i < n; i++)
			{
				var c:DisplayObject = getChildAt(i);
				if (!(c is TextField))
				{
					c.x = (w - c.width) / 2;
					c.y = 0;
				}
			}
		}
	}

}

}