How to add a new attribute via xsl in an existing xml structure

[Sumit Aggarwal]

Problem : I need to add a new variable DateTime(Integer type) in the current hierarchy(of dbPublish.xml) as a event attribute. For example,

<?xml version="1.0" encoding="UTF-8" ?>
<?xml-stylesheet type="text/xsl" href="dbPublish.xsl"?>
<dbpublish>
<type id="210003534" displayOrder="0" name="German" url="DEFINE_IN_CUSTOMER_SPECIFIC_CONFIG/t/210003534">
<event id="1556561" displayOrder="0" classId="110000045" typeId="210003534" typeName="German" name="EventI_197_12:40" date="2011-08-02" time="12:40:26" DateTime=”20110802124026” status="A" suspend="" sort="MTCH" channels="I" country="" flags="">
<market id="2092062" displayOrder="1" name="Handicap betting 40 mins only" type="-" sort="--" status="A" birIndex="" handicap="" unformattedHandicap="" forcastAvailable="N" tricastAvailable="N" eachwayAvailable="N" startingPriceAvailable="N" livePriceAvailable="Y" guarenteedPriceAvailable="N" channels="I" url="DEFINE_IN_CUSTOMER_SPECIFIC_CONFIG/m/2092062">
        			<outcome id="18730605" displayOrder="1" name="S1" status="A" odds="510/1000" oddsDecimal="1.51" channels="I" runnerNumber="" resultType="-" handicap=""/>
        			<outcome id="18730606" displayOrder="2" name="S2" status="A" odds="330/1000" oddsDecimal="1.33" channels="I" runnerNumber="" resultType="-" handicap=""/>
      		</market>
    	</event>
</type>
</dbpublish>

Partial Solution:

I have added the code in red in dbPublish.xsl, which will give me DateTime=”20110802124026”

<xsl:stylesheet version='1.0'
    xmlns:xsl='http://www.w3.org/1999/XSL/Transform' xmlns:dt="XSLT.Extension.MyDateFormat">
	<!-- Copyright 2007 Endeca Technologies, Inc. All Rights Reserved. -->
	
	
    <xsl:output method="xml" indent="yes" encoding="UTF-8"/>
 	
	<xsl:template match="/">
		<xsl:element name="RECORDS">
				
			<!-- apply templates for each "repeating element" representing a single record -->
			<!-- ADD RECORD SELECTORS HERE -->
			<xsl:apply-templates select="//outcome"/>		
		</xsl:element>
	</xsl:template>
	
	<!-- one template with RECORD element for each template type applied above -->
	<!-- ADD RECORD SELECTORS HERE -->
	<xsl:template match="outcome">
		<xsl:element name="RECORD"> 
			<xsl:apply-templates select="../../../../@*"/>
			<xsl:apply-templates select="../../../@*"/>
			<xsl:apply-templates select="../../@*"/>
			<xsl:apply-templates select="../@*"/>
			<xsl:apply-templates select="@*"/>						
		</xsl:element>
	</xsl:template> 

	 <xsl:template match="@*">
		<xsl:element name="PROP">
    				<xsl:attribute name="NAME">
    					<xsl:value-of select="name(../.)"/><xsl:text>_</xsl:text><xsl:value-of select="name()"/>													
    				</xsl:attribute>
					<xsl:element name="PVAL">
						<xsl:value-of select="."/>	
					</xsl:element>			
    		</xsl:element>
	</xsl:template>

<xsl:template match="event">
			<xsl:element name="PROP">
				<xsl:attribute name="NAME">
					<xsl:text>DateTime</xsl:text>
				</xsl:attribute>
				<xsl:element name="PVAL">
    				<xsl:call-template name="FormatDate">
						<xsl:with-param name="Date" select="@date"/>
					</xsl:call-template>
					<xsl:call-template name="FormatTime">
						<xsl:with-param name="Time" select="@time"/>
					</xsl:call-template>
				</xsl:element>					
		</xsl:element>
 	</xsl:template>
	
	<xsl:template name="FormatDate">
		<xsl:param name="Date" />
				<xsl:variable name="year">
				  <xsl:value-of select="substring($Date,1,4)" />
				</xsl:variable>

				<xsl:variable name="month-temp">
				  <xsl:value-of select="substring-after($Date,'-')" />
				</xsl:variable>

				<xsl:variable name="month">
				  <xsl:value-of select="substring-before($month-temp,'-')" />
				</xsl:variable>

				<xsl:variable name="day-temp">
				  <xsl:value-of select="substring-after($month-temp,'-')" />
				</xsl:variable>

				<xsl:variable name="day">
				  <xsl:value-of select="substring($day-temp,1,2)" />
				</xsl:variable>
				
				 <xsl:value-of select="$year"/>				 
				 <xsl:value-of select="$month"/>				  
				 <xsl:value-of select="$day"/>
			
	</xsl:template>	 
	
	<xsl:template name="FormatTime">
		<xsl:param name="Time" />
				<xsl:variable name="hour">
				  <xsl:value-of select="substring($Time,1,2)" />
				</xsl:variable>

				<xsl:variable name="hour-temp">
				  <xsl:value-of select="substring-after($Time,':')" />
				</xsl:variable>

				<xsl:variable name="min">
				  <xsl:value-of select="substring-before($hour-temp,':')" />
				</xsl:variable>

				<xsl:variable name="min-temp">
				  <xsl:value-of select="substring-after($hour-temp,':')" />
				</xsl:variable>

				<xsl:variable name="sec">
				  <xsl:value-of select="substring($min-temp,1,2)" />
				</xsl:variable>
				
				 <xsl:value-of select="$hour"/>				 
				 <xsl:value-of select="$min"/>				  
				 <xsl:value-of select="$sec"/>
			
	</xsl:template>	     
</xsl:stylesheet>

Now, where should I call my event template so as to put my attribute at the desired location.


Please provide your valuable inputs.

[g tsuji]

If you mean the xml document itself does not actually have DateTime attribute on its "event" element, you can do it like this, modifying the attribute template and adding one named template "DateTime" below.

    <xsl:template match="@*">   
        <xsl:element name="PROP">   
            <xsl:attribute name="NAME">   
                <xsl:value-of select="name(../.)"/><xsl:text>_</xsl:text><xsl:value-of select="name()"/>
            </xsl:attribute>   
            <xsl:element name="PVAL">
                <xsl:value-of select="."/>
            </xsl:element>               
        </xsl:element>
        <xsl:if test="name() = 'time' and name(parent::*) = 'event' and parent::*/@date">
            <xsl:call-template name="DateTime" />
        </xsl:if>
    </xsl:template>

    <xsl:template name="DateTime">
        <xsl:element name="PROP">   
            <xsl:attribute name="NAME">   
                <xsl:value-of select="name(parent::*)"/><xsl:text>_</xsl:text><xsl:value-of select="'DateTime'"/>
            </xsl:attribute>
            <xsl:element name="PVAL">
                <xsl:value-of select="concat(translate(parent::*/@date,'-',''), translate(parent::*/@time,':',''))"/>       
            </xsl:element>
        </xsl:element>
    </xsl:template>

You can thereby take out the template for event, and named template "FormatDate" and "FormatTime".